emacs でお気に入りの設定 2025

(setq skk-user-directory "~/.emacs.d/.ddskk")

(setq skk-use-azik t)

;; (setq skk-sticky-key [convert])
(setq skk-sticky-key [henkan])

(setq skk-rom-kana-rule-list '(("z " nil "　")))

(setq confirm-kill-emacs 'y-or-n-p)

(ffap-bindings)

(global-set-key (kbd "C-c m") nil)

(define-key key-translation-map (kbd "C-h") (kbd "<DEL>"))

;; PC 切り換え機に割り当てるので
(global-set-key (kbd "<Scroll_Lock>") 'ignore)

;; backup に 関する設定
;; http://yohshiy.blog.fc2.com/blog-entry-319.html
;; バックアップファイル (foo.txt~)
(setq backup-directory-alist
      '((".*" . "~/.emacs.d/backup/emacs-backup-files")))
;; 番号付けによる複数保存
(setq version-control     t)  ;; 実行の有無
(setq kept-new-versions   10)  ;; 最新の保持数
(setq kept-old-versions   10)  ;; 最古の保持数
(setq delete-old-versions t)  ;; 範囲外を削除

;; 自動保存ファイル (#foo.txt#)
(setq auto-save-file-name-transforms
      '((".*" "~/.emacs.d/backup/auto-saved-files" t)))
;; 保存の間隔
(setq auto-save-timeout 10)     ;; 秒   (デフォルト : 30)
(setq auto-save-interval 100)   ;; 打鍵 (デフォルト : 300)

;; 自動保存リストファイル (~/.emacs.d/auto-save-list/.saves-xxxx)
(setq auto-save-list-file-prefix "~/tmp/.saves-")

;; ロックファイル (.#foo.txt)
;; 作成しない
(setq create-lockfiles nil)

;;; markdown-to-org.el --- Convert Markdown to Org-mode format using pandoc

;; Copyright (C) 2023  Your Name

;; Author: Your Name <your.name@example.com>
;; URL: https://github.com/yourname/markdown-to-org
;; Version: 0.1.0
;; Keywords: markdown, org-mode, pandoc, convert
;; Package-Requires: ((emacs "24.4"))
;; License: MIT

;;; Commentary:
;;
;; This package provides functions to convert Markdown text into Emacs
;; org-mode text by using pandoc. You can use it in a buffer, region, or
;; an external file.

;;; Code:

(defgroup markdown-to-org nil
  "Convert Markdown to Org-mode with pandoc."
  :group 'tools
  :prefix "markdown-to-org-")

(defcustom markdown-to-org-pandoc-path "pandoc"
  "Path to the pandoc command."
  :type 'string
  :group 'markdown-to-org)

(defun markdown-to-org--run-pandoc (beg end)
  "Run pandoc on the region between BEG and END to convert Markdown to Org."
  (let ((pandoc-cmd (format "%s -f markdown -t org" markdown-to-org-pandoc-path)))
    (shell-command-on-region
     beg
     end
     pandoc-cmd
     ;; Insert results in current buffer, replacing the region
     t
     ;; Output buffer
     t)))

;;;###autoload
(defun markdown-to-org-convert-region (beg end)
  "Convert the Markdown in region (BEG to END) to Org-mode in-place."
  (interactive "r")
  (markdown-to-org--run-pandoc beg end)
  (message "Converted Markdown region to Org-mode!"))

;;;###autoload
(defun markdown-to-org-convert-buffer ()
  "Convert the entire buffer from Markdown to Org-mode."
  (interactive)
  (markdown-to-org--run-pandoc (point-min) (point-max))
  (message "Converted entire buffer from Markdown to Org-mode!"))

;;;###autoload
(defun markdown-to-org-convert-file (input-file output-file)
  "Convert INPUT-FILE (Markdown) to OUTPUT-FILE (Org-mode) using pandoc."
  (interactive "fMarkdown file to convert: \nFOutput Org file: ")
  (let ((pandoc-cmd (format "%s -f markdown -t org %s -o %s"
                            markdown-to-org-pandoc-path
                            (shell-quote-argument (expand-file-name input-file))
                            (shell-quote-argument (expand-file-name output-file)))))
    (shell-command pandoc-cmd)
    (message "Converted %s to %s" input-file output-file)))

(provide 'markdown-to-org)

;;; markdown-to-org.el ends here

;; -*- Mode: Emacs-Lisp ; Coding: utf-8 -*-
(require 'org)

;; 時間をコピーする
(defun copy-time ()
  "現在時間をキルリングにセットする"
  (interactive)
  (kill-new (format-time-string "%Y-%m-%d-%H%M%S_")))

(defun get-date ()
  (interactive)
  (let ((org-time-stamp-formats org-time-stamp-custom-formats))
    (org-insert-time-stamp (current-time) nil)))

(defun get-dtime ()
  (interactive)
  (let ((org-time-stamp-formats org-time-stamp-custom-formats))
    (org-insert-time-stamp (current-time) t)))

(provide 'get-and-copy-time-and-date)

; -*- Mode: Emacs-Lisp ; Coding: utf-8 -*-
;;; フレームを半透明にする
;; (set-frame-parameter nil 'alpha 75)
(defun frame-transparency (n)
  "alphaをnに変更する"
  (interactive "n value: ")
  (set-frame-parameter nil 'alpha n))

(provide 'frame-transparency)

;; -*- Mode: Emacs-Lisp ; Coding: utf-8 -*-

;; 現在行をコピーして下の行に貼り付ける
(defun duplicate-this-line-forward (n)
  "Duplicates the line point is on.  The point is next line.
 With prefix arg, duplicate current line this many times."
  (interactive "p")
  (when (eq (point-at-eol)(point-max))
    (save-excursion (end-of-line) (insert "\n")))
  (save-excursion
    (beginning-of-line)
    (dotimes (i n)
      (insert-buffer-substring (current-buffer) (point-at-bol)(1+ (point-at-eol))))))

(provide 'duplicate-this-line-forward)

;;; my-dired-extensions.el --- 自作 Dired 拡張や OS 連携

;;; Code:

(require 'dired)   ;; dired を拡張するので一応読み込む
(require 'cl-lib)
(require 'recentf)

;;----------------------------------------
;; OS 判定 & OS ごとにファイルを開くコマンドを決定するコード
;;----------------------------------------
(defun os-type ()
  "現在の OS タイプを返す (cygwin, linux, darwin など)."
  (let ((uname-str (shell-command-to-string "uname")))
    (cond ((string-match "CYGWIN" uname-str)
           'cygwin)
          ((string-match "Linux" uname-str)
           'linux)
          ((string-match "Darwin" uname-str)
           'darwin))))

(defun os-open-command-name (os-type)
  "OS-TYPE に応じて実行できるファイルオープンコマンドのパスを探す."
  (let ((command-name-list (cl-case os-type
                             ('cygwin '("sglstart" "cygstart"))
                             ('linux  '("sglstart" "wslstart" "xdg-open" "gnome-open"))
                             ('darwin '("open")))))
    (catch 'loop
      (dolist (command-name command-name-list)
        (let* ((command1 (concat "which " command-name " 2> /dev/null"))
               (command2 (if (file-remote-p default-directory)
                             ;; リモートではログインシェルでコマンドを実行する
                             (format "$0 -l -c '%s' 2> /dev/null" command1)
                           command1))
               (absolute-path-command-name
                (replace-regexp-in-string
                 "\n" ""
                 (shell-command-to-string command2))))
          (unless (string= absolute-path-command-name "")
            (throw 'loop absolute-path-command-name)))))))

;; コマンド名をホストごとにキャッシュ
(defvar os-open-command-cache nil
  "ホスト名をキーにして (OS-TYPE OS-OPEN-COMMAND-NAME) を保持するキャッシュ変数.")

(defun os-open-command-cache ()
  "ホストごとのコマンドキャッシュを返す."
  (let* ((hostname (if (file-remote-p default-directory)
                       (let* ((vec (tramp-dissect-file-name default-directory))
                              (host (tramp-file-name-host vec))
                              (user (tramp-file-name-user vec)))
                         (if user
                             (format "%s@%s" user host)
                           host))
                     "<localhost>")))
    (cdr (or (assoc hostname os-open-command-cache)
             (let* ((type (os-type))
                    (cmd  (os-open-command-name type)))
               (car (push (cons hostname (list type cmd))
                          os-open-command-cache)))))))

;;----------------------------------------
;; OS で直接ファイルを開く
;;----------------------------------------
(defun os-open-command (filename)
  "FILENAME を OS のコマンドで開く."
  (interactive "FOpen file: ")
  (let* ((filename (expand-file-name filename))
         (default-directory (file-name-directory filename)))
    (let* ((cache (os-open-command-cache))
           (type  (nth 0 cache))
           (cmd   (nth 1 cache)))
      (if cmd
          (let ((localname (if (file-remote-p filename)
                               (tramp-file-name-localname
                                (tramp-dissect-file-name filename))
                             filename)))
            (message "%s %s" (file-name-nondirectory cmd) localname)
            (cond
             ((and (eq type 'linux)
                   (not (file-remote-p default-directory)))
              ;; Linux + ローカル環境
              (let (process-connection-type)
                (start-process "os-open-command" nil cmd localname)))
             (t
              ;; リモートでも使えるように shell-command-to-string
              (shell-command-to-string
               (format "%s %s &" cmd (shell-quote-argument localname))))))
        (message "利用できるコマンドがありません。")))))

(defun os-open-command-2 (filename)
  "FILENAME を recentf に登録してから OS で開く."
  (interactive "FOpen file with recentf: ")
  (recentf-push filename)
  (os-open-command filename))

;;----------------------------------------
;; Dired でキー操作・マウス操作をしたとき OS で開く
;;----------------------------------------
(define-key dired-mode-map (kbd "W")
  (lambda ()
    (interactive)
    (os-open-command-2 (dired-get-file-for-visit))))

(define-key dired-mode-map [mouse-2]
  (lambda (event)
    (interactive "e")
    (dired-mouse-find-file event 'os-open-command-2 'os-open-command-2)))

(define-key dired-mode-map (kbd "E")
  (lambda ()
    (interactive)
    (os-open-command (dired-current-directory))))

(define-key dired-mode-map [mouse-3]
  (lambda (event)
    (interactive "e")
    (mouse-select-window event)
    (os-open-command (dired-current-directory))))

;;----------------------------------------
;; OS で開きたいファイルの拡張子リスト & find-file のアドバイス
;;----------------------------------------
(setq os-open-file-suffixes
      '("doc" "docx"
        "xls" "xlsx"
        "ppt" "pptx"
        "mdb" "mdbx"
        "vsd" "vdx" "vsdx"
        "mpp"
        "pdf"
        "bmp" "jpg"
        "odt" "ott"
        "odg" "otg"
        "odp" "otp"
        "ods" "ots"
        "odf"))

(defun os-open-file-p (filename)
  "FILENAME が os-open-file-suffixes の拡張子を持つ通常ファイルなら t."
  (when (file-regular-p filename)
    (let ((ext (file-name-extension filename)))
      (when (and ext
                 (member (downcase ext) os-open-file-suffixes))
        t))))

(advice-add 'find-file :around
            (lambda (orig-fun &rest args)
              (let* ((file-name (nth 0 args))
                     (target-name (or (file-symlink-p file-name)
                                      file-name)))
                (if (os-open-file-p target-name)
                    (os-open-command-2 target-name)
                  (apply orig-fun args)))))

;;----------------------------------------
;; dired-guess-shell の設定
;;----------------------------------------
(setq dired-guess-shell-alist-user
      '(("\\.doc$"  (nth 1 (os-open-command-cache)))
        ("\\.docx$" (nth 1 (os-open-command-cache)))
        ("\\.xls$"  (nth 1 (os-open-command-cache)))
        ("\\.xlsx$" (nth 1 (os-open-command-cache)))
        ("\\.ppt$"  (nth 1 (os-open-command-cache)))
        ("\\.pptx$" (nth 1 (os-open-command-cache)))
        ("\\.mdb$"  (nth 1 (os-open-command-cache)))
        ("\\.mdbx$" (nth 1 (os-open-command-cache)))
        ("\\.vsd$"  (nth 1 (os-open-command-cache)))
        ("\\.vdx$"  (nth 1 (os-open-command-cache)))
        ("\\.vsdx$" (nth 1 (os-open-command-cache)))
        ("\\.mpp$"  (nth 1 (os-open-command-cache)))
        ("\\.pdf$"  (nth 1 (os-open-command-cache)))
        ("\\.bmp$"  (nth 1 (os-open-command-cache)))
        ("\\.odt$"  (nth 1 (os-open-command-cache)))
        ("\\.ott$"  (nth 1 (os-open-command-cache)))
        ("\\.odg$"  (nth 1 (os-open-command-cache)))
        ("\\.otg$"  (nth 1 (os-open-command-cache)))
        ("\\.odp$"  (nth 1 (os-open-command-cache)))
        ("\\.otp$"  (nth 1 (os-open-command-cache)))
        ("\\.ods$"  (nth 1 (os-open-command-cache)))
        ("\\.ots$"  (nth 1 (os-open-command-cache)))
        ("\\.odf$"  (nth 1 (os-open-command-cache)))))

;;----------------------------------------
;; Dired を 2つのウィンドウで開いているときに
;; other-window へ copy/move/symlink する
;;----------------------------------------
(defun dired-do-copy-dwim ()
  (interactive)
  (let ((dired-dwim-target t))
    (dired-do-copy)))

(defun dired-do-rename-dwim ()
  (interactive)
  (let ((dired-dwim-target t))
    (dired-do-rename)))

(defun dired-do-symlink-dwim ()
  (interactive)
  (let ((dired-dwim-target t))
    (dired-do-symlink)))

(define-key dired-mode-map (kbd "c") 'dired-do-copy-dwim)
(define-key dired-mode-map (kbd "r") 'dired-do-rename-dwim)
(define-key dired-mode-map (kbd "s") 'dired-do-symlink-dwim)
(define-key dired-mode-map (kbd "e") 'wdired-change-to-wdired-mode)

;; dired-start-eshell を別の関数に remap
(define-key dired-mode-map [remap dired-do-shell-command] 'dired-start-eshell)

(provide 'dired-extensions)

;;; dired-extensions.el ends here

;; -*- Mode: Emacs-Lisp ; Coding: utf-8 -*-

;; バッファ名をコピーする
(defun copy-buffer-name ()
  (interactive)
  (kill-new (buffer-name)))

;; フルパスをコピーする
(defun copy-fullpath-buffer-file-name ()
  "カレントバッファのファイル名 (フルパス) をコピー"
  (interactive)
  (if buffer-file-name
      (progn
        (kill-new buffer-file-name)
        (message buffer-file-name))
    (message "ファイルじゃありません")))

(provide 'copy-buffer-name)

; -*- Mode: Emacs-Lisp ; Coding: utf-8 -*-
;; source: http://steve.yegge.googlepages.com/my-dot-emacs-file
(defun rename-file-and-buffer (new-name)
  "Renames both current buffer and file it's visiting to NEW-NAME."
  (interactive "sNew name: ")
  (let ((name (buffer-name))
        (filename (buffer-file-name)))
    (if (not filename)
        (message "Buffer '%s' is not visiting a file!" name)
      (if (get-buffer new-name)
          (message "A buffer named '%s' already exists!" new-name)
        (progn
          (rename-file filename new-name 1)
          (rename-buffer new-name)
          (set-visited-file-name new-name)
          (set-buffer-modified-p nil))))))

(provide 'rename-file-and-buffer)

;; -*- Mode: Emacs-Lisp ; Coding: utf-8 -*-

(defvar wrap-pairs-alist '(( "(" . ")")
                           ( "[" . "]")
                           ( "{" . "}")
                           ( "<" . ">")
                           ( "\"" . "\"")
                           ( "'" . "'")))

(defun get-right-wrap (left-wrap)
  "左の囲み文字から右の囲み文字を取得する。"
  (cdr (assoc left-wrap wrap-pairs-alist)))

(defun wrap-region-with-auto-right (start end left-wrap)
  "リージョンを指定された囲み文字で囲む。右の囲み文字は左の囲み文字から自動で類推される。"
  (let* ((right-wrap (get-right-wrap left-wrap))
         (end-marker (set-marker (make-marker) end)))
    (save-excursion
      (goto-char start)
      (insert left-wrap)
      (goto-char (marker-position end-marker))
      (insert (or right-wrap "")))
    (set-marker end-marker nil))) ; マーカーをクリーンアップ

(defun wrap-region-or-insert (left-wrap)
  "リージョンが選択されていればリージョンを指定された囲み文字で囲む。
リージョンが選択されていなければ囲み文字を挿入し、カーソルを囲み文字の間に移動する。"
  (interactive)
  (if (use-region-p)
      (wrap-region-with-auto-right (region-beginning) (region-end) left-wrap)
    (let ((right-wrap (get-right-wrap left-wrap)))
      (insert left-wrap (or right-wrap ""))
      (backward-char (length (or right-wrap "")))))
  (deactivate-mark)) ; リージョンの選択を解除

(provide 'wrap-region-or-insert)

(defun get-os-version ()
  "Return a string describing the OS version."
  (cond
   ;; macOS
   ((eq system-type 'darwin)
    (string-trim (shell-command-to-string "sw_vers -productVersion")))

   ;; Linux
   ((eq system-type 'gnu/linux)
    (or
     ;; まずは lsb_release があればそれを使う
     (let ((lsb (executable-find "lsb_release")))
       (when lsb
         (string-trim
          (shell-command-to-string (concat lsb " -d | cut -f2-")))))
     ;; なければ /etc/os-release を試す
     (when (file-readable-p "/etc/os-release")
       (with-temp-buffer
         (insert-file-contents "/etc/os-release")
         (goto-char (point-min))
         (if (re-search-forward "^PRETTY_NAME=\"\\(.*?\\)\"" nil t)
             (match-string 1)
           "Unknown Linux distribution")))
     ;; 最後の手段: uname -r などで kernel version を返す
     (string-trim (shell-command-to-string "uname -r"))))

   ;; Windows
   ((eq system-type 'windows-nt)
    (string-trim (shell-command-to-string "ver")))

   ;; 上記以外
   (t "Unknown OS")))

(defun os-version ()
  "Display the OS version in *Messages*."
  (interactive)
  (message "Your OS version: %s" (get-os-version)))